;; timer - Copyright 2007 by Michael Kohn
;; Email: mike ta mikekohn.net
;;   Web: http://www.mikekohn.net/
;;
;; Simple example of how to use timers on the ATmega168.

.include "m168def.inc"

; note: CLKSEL 0010

.dseg

.cseg

.org 0x000
  rjmp start
.org 0x01a
  rjmp handler

.org 0x020

start:
  ;; Set up stack ptr
  ldi r16, RAMEND>>8
  out SPH, r16
  ldi r16, RAMEND&255
  out SPL, r16

  ;; Set up LED default
  ser r17
  out DDRB, r17             ; entire port B is output
  ldi r18, 2|16|32
  out PORTB, r18            ; turn on bit 2 and 3

  ;; Set up Counter
  eor r17, r17
  sts TCCR1A, r17               ; normal counting (0xffff is top, count up)
  sts TCCR1C, r17               ; no compare 
  ldi r17, (1<<CS10)
  sts TCCR1B, r17               ; prescale = 1 from clock source
  ldi r17, (1<<TOIE1)
  sts TIMSK1, r17               ; enable interrupt on overflow
  lds r17, PRR
  andi r17, 255 ^ (1<<PRTIM1)
  sts PRR, r17                  ; turn of power management bit on TIM1

  ldi r19, 122
  ldi r20, 2
  ldi r21, 10                   ; count 10 blinks
  sei

loop:
  rjmp loop

handler:
  subi r19, 1               ; if not counted 122 interrupts, exit
  brne exit_handler

  eor r18, r20
  out PORTB, r18            ; toggle LED
  ldi r19, 122              ; reset 122 interrupt counter

  subi r21, 1               ; count 10 blinks
  brne exit_handler

  or r18, r20
  out PORTB, r18            ; turn off current LED

  cpi r20, 24
  breq restart_seq

  ldi r21, 10               ; reset 10 blink counter
  lsl r20                   ; make it blink another LED
  cpi r20, 8                ; see if LED 2 is set
  brne exit_handler
  ldi r20, 24               ; blink LED 2 and buzz buzzer

exit_handler:
  reti

restart_seq:
  ldi r18, 2|16|32
  ldi r19, 122
  ldi r20, 2
  ldi r21, 10                   ; count 10 blinks
  out PORTB, r18            ; toggle LED
reti

signature:
.db "Timer - Copyright 2007 - Michael Kohn - Version 0.13"